C  This is a DEC Fortran program to calculate all possible thread
C  pitches for the Sherline lathe.  It will compile and run on a
C  Digital Alpha system running OpenVMS, and may run on other systems
C  with no changes, or few changes.
C
C  Jim Kirkpatrick, jimkirk at uwyo.edu

      IMPLICIT NONE
      INTEGER IA,IB,IC,ID
      REAL A,B,C,D
C  There are 12 gears supplied with the threading option:
      REAL GEARS(12)
      DATA GEARS /20,22,24,26,28,30,32,34,35,36,38,40/
C  The standard leadscrew is 20 turns per inch.  If you have the
C  metric version of the Sherline lathe, I think you could just
C  convert the metric pitch to equivalent threads per inch and
C  substitute that, below.
      REAL LEADSCREW
      PARAMETER (LEADSCREW=20.)
      REAL TPI,INCHPITCH,METRICPITCH

C  The following computations are based on right-hand threads but
C  are equally correct for left-hand.  One must either insert an
C  idler gear "E" for right-hand, or idler gears "F" and "G" for
C  left-hand.  This code makes no attempt to see if any combination
C  of idlers will actually fit, so some results may be impossible!

C  Also it is assumed, for computations, that the owner has the
C  optional 35-tooth gear (p/n 3135?), and as many gears as needed.
C  However, the standard kit is only supplied with one of each size
C  except for two 20T gears, so again this program may come up with
C  combinations that are impossible with standard gears.  In these
C  cases, some other combination may exist that yields the same
C  result, or the owner may need to buy some extra gears.  I'm
C  trying to be thorough, not correct!

      DO IA=1,2   !   The "A" gear is one of two sizes
        IF (IA.EQ.1) A=50
        IF (IA.EQ.2) A=100
        DO IB=1,3   !   The "B" gear is one of three sizes
          IF (IB.EQ.1) B=100
          IF (IB.EQ.2) B=127
          IF (IB.EQ.3) B=50
          DO IC=1,12   !   The "C" gear is picked from the list
            C=GEARS(IC)
            DO ID=1,12
              D=GEARS(ID)
              TPI=LEADSCREW/((A/B)/(D/C))
              INCHPITCH=1./TPI
              METRICPITCH=INCHPITCH*25.4
              PRINT 100,INT(A),INT(B),INT(C),INT(D),TPI,
     -                  INCHPITCH,METRICPITCH
100           FORMAT (4I4,3X,F7.3,3X,F6.4,3X,F6.4)
            END DO
          END DO
        END DO
      END DO

      END